@echo off & setlocal & chcp 437>nul & graftabl 936>nul
if "%~1"=="" (
echo.
echo.＝文本文件加解密程序 :: qzwqzw :: 2007-06-05 :: Release 7
echo.
echo.＝原理：使用DEBUG 腳本動態(tài)生成可執(zhí)行程序對輸入文件逐字節(jié)異或編碼
echo.
echo.＝特性：加解密互逆，多文件操作，單數(shù)字密鑰
echo.
set /p file=－請輸入文件名（支持通配符，默認為 .\*.txt）：
set /p pass=－請輸入密鑰（一位0~F的十六進制數(shù)，默認為0）：
echo.
) else (
set "file=%~1"
set "pass=%~2"
)
if "%file%"=="" set file=*.txt
if "%pass%"=="" set pass=0
if not exist "%file%" echo ！找不到文件: "%file%" && goto end
:: 生成并執(zhí)行 DEBUG 腳本，生成轉換程序
echo e 100 B4 06 B2 FF CD 21 74 08 34 E%pass% 88 C2 CD 21 EB F0 C3>_codec.scr
for %%s in (rcx 11 n_codec.com w q) do echo %%s>>_codec.scr
debug <_codec.scr | find "Error">nul && echo ！密鑰錯誤: "%pass%" && goto :end
:: 搜索指定路徑所有匹配文件進行轉換
for %%f in ("%file%") do set "fPath=%%~dpf"
for /f "delims=" %%f in ('dir /a/b/od "%file%" 2^>nul') do (
(set "fIn=%fPath%%%f") && (set "fOut=%fPath%#%%f")
call :Codec
)
echo.
if exist _codec.* del _codec.*
if "%~0"=="%~f0" pause
goto :eof
:Codec
if exist "%fOut%" echo ！已存在文件: "%fOut%" && pause && goto :eof
echo ＋正在轉換 "%fIn%" ...
if exist _codec.com _codec.com < "%fIn%" > "%fOut%"
if not exist "%fOut%" echo ！轉換失敗，未生成 "%fOut%" && pause