用bat實現(xiàn)的自動關(guān)機(jī)的代碼

更新時間：2007年05月15日 00:00:00 作者：

有時候我們需要自動關(guān)機(jī)，其實結(jié)合windows任務(wù)計劃+一段批處理就可以試下，這里簡單的介紹下，一般我們在服務(wù)器上使用的多是自動重啟

一般情況下我們都是使用shutdown來實現(xiàn)關(guān)機(jī)與重啟

用法: shutdown [/i | /l | /s | /r | /a | /p | /h | /e] [/f]
[/m \\computer][/t xxx][/d [p:]xx:yy [/c "comment"]]

沒有參數(shù) 顯示幫助。這與鍵入 /? 是一樣的
/? 顯示幫助。這與不鍵入任何選項是一樣的
/i 顯示圖形用戶界面(GUI)。
這必須是第一個選項
/l 注銷。這不能與 /m 或 /d 選項一起使用
/s 關(guān)閉計算機(jī)
/r 關(guān)閉并重啟動計算機(jī)
/a 放棄系統(tǒng)關(guān)閉。
這只能在超時過程中使用
/p 關(guān)閉本地計算機(jī)，沒有超時或警告。
這只能與 /d 選項一起使用
/h 休眠本地計算機(jī)。
這只能與 /f 選項一起使用
/e 將計算機(jī)的意外關(guān)閉原因記入文檔
/m \\computer 指定目標(biāo)計算機(jī)
/t xxx 設(shè)置關(guān)閉前的超時為 xxx 秒。
有效范圍是 0-600，默認(rèn)為 30
/c "comment" 重啟動或關(guān)閉的原因的注釋。
最大允許 127 個字符
/f 強(qiáng)制正在運(yùn)行的應(yīng)用程序關(guān)閉而不事先警告用戶
/d [p:]xx:yy 提供重啟動或關(guān)閉的原因
p 表明重啟動或關(guān)閉是計劃內(nèi)的
xx 是主要原因號(小于 256 的正整數(shù))
yy 是次要原因號(小于 65536 的正整數(shù))

重啟
shutdown /r /f

關(guān)機(jī)
shutdown /s /f

先來個簡單功能版本的

復(fù)制代碼代碼如下:

@echo off
mode con lines=25
title 定時關(guān)機(jī)
color 1f
cls
echo.
echo.
echo.
echo.
echo              時間使用24小時制(如2:15、12:00)，可以輸入多個時間點
echo.
echo                           多個時間點用空格分隔
echo.
echo.
echo ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
echo.
set times=
set /p times=                     請輸入關(guān)機(jī)時間：
:: 以下語句實現(xiàn)每個星期的每一天指定時間關(guān)機(jī)
:: 如果要換成每個月的某幾天，請改字母為數(shù)字，并用逗號分隔
:: 以下代碼沒有錯誤檢測語句，輸入時間的時候務(wù)必按照指定格式輸入
:: 可以用在CMD窗口用at命令來查看計劃任務(wù)
if not "%times%"=="" for %%i in (%times%) do (
    at %%i /every:M,T,W,Th,F,S,Su shutdown -s
)

下面是多功能版的，適合學(xué)習(xí)bat的朋友

復(fù)制代碼代碼如下:

@ECHO off 
TITLE 自動關(guān)機(jī)程序 作者:廖曉青 
:start 
CLS 
COLOR 1f 
rem 使用COLOR命令對控制臺輸出顏色進(jìn)行更改 
MODE con: COLS=41 LINES=18 
rem MODE語句為設(shè)定窗體的寬和高 
set tm1=%time:~0,2% 
set tm2=%time:~3,2% 
set tm3=%time:~6,2% 
ECHO %date% %tm1%點%tm2%分%tm3%秒 
ECHO ========================================= 
ECHO 請選擇要進(jìn)行的操作，然后按回車 
ECHO ─────────────── 
ECHO. 
ECHO 1. 定時關(guān)機(jī) 
ECHO 2. 倒計時關(guān)機(jī) 
ECHO 3. 刪除定時關(guān)機(jī)任務(wù) 
ECHO 4. 查看任務(wù)狀態(tài) 
ECHO 5. 刷新當(dāng)前時間 
ECHO 6. 重新啟動 
ECHO 7. 鎖定計算機(jī) 
ECHO 8. 注銷 
ECHO 9. 退出 
ECHO. 

:cho 
SET Choice= 
SET /P Choice=選擇: 
rem 設(shè)定變量"Choice"為用戶輸入的字符 
IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1% 
rem 如果輸入大于1位,取第1位,比如輸入132,則返回值為1 
ECHO. 
IF /I "%Choice%"=="1" GOTO SetHour 
IF /I "%Choice%"=="2" GOTO outtime 
IF /I "%Choice%"=="3" GOTO delAt 
IF /I "%Choice%"=="4" GOTO view 
IF /I "%Choice%"=="5" GOTO start 
IF /I "%Choice%"=="6" GOTO restart 
IF /I "%Choice%"=="7" GOTO lock 
IF /I "%Choice%"=="8" GOTO logoff 
IF /I "%Choice%"=="9" GOTO end 
rem 為避免出現(xiàn)返回值為空或含空格而導(dǎo)致程序異常,需在變量外另加雙引號 
rem 注意,IF語句需要雙等于號 
rem 如果輸入的字符不是以上數(shù)字,將返回重新輸入 
ECHO 選擇無效，請重新輸入 
ECHO. 
GOTO cho 

:SetHour 
CLS 
ECHO. 
SET ask= 
SET /p ask=是否設(shè)定為每天執(zhí)行關(guān)機(jī)命令(y/n): 
IF NOT "%ask%"=="" SET ask=%ask:~0,1% 
IF /I "%ask%"=="y" GOTO yes 
IF /I "%ask%"=="n" GOTO no 
GOTO SetHour 

:yes 
ECHO 請指定24小時制式時間,格式為 小時:分鐘 
SET shutdowntime= 
SET /p shutdowntime=輸入: 
at %shutdowntime% /every:M,T,W,Th,F,S,Su tsshutdn 0 /delay:0 /powerdown >nul 
rem 設(shè)定為每周的星期一至星期日,即為每天 
IF NOT errorlevel 1 GOTO ok 
rem 如果輸入正確,就執(zhí)行ok段的語句 
ECHO %shutdowntime% 不是標(biāo)準(zhǔn)的時間格式,請重新輸入 
ECHO. 
GOTO yes 

:no 
ECHO 請指定24小時制式時間,格式為 小時:分鐘 
SET shutdowntime= 
SET /p shutdowntime=輸入: 
at %shutdowntime% tsshutdn 0 /delay:0 /powerdown >nul 
IF NOT errorlevel 1 GOTO ok 
ECHO %shutdowntime% 不是標(biāo)準(zhǔn)的時間格式,請重新輸入 
ECHO. 
GOTO no 

:ok 
ECHO. 
SET h=%shutdowntime:~1,1% 
SET ah=%shutdowntime:~0,1% 
SET am=%shutdowntime:~2,2% 
SET bh=%shutdowntime:~0,2% 
SET bm=%shutdowntime:~3,2% 
IF "%h%"==":" ( 
SET HM=%ah%時%am%分 
) ELSE ( 
SET HM=%bh%時%bm%分) 
rem 如果輸入h:mm則HM=h時mm分,否則HM=hh時mm分 
IF /I "%ask%"=="y" ECHO 系統(tǒng)將于每天的%HM%關(guān)閉 
IF /I "%ask%"=="n" ECHO 系統(tǒng)將于%HM%關(guān)閉 
ECHO 設(shè)定完畢! 按任意鍵繼續(xù)... 
PAUSE >nul 
GOTO start 

:outtime 
CLS 
ECHO. 
ECHO 請輸入倒計時秒數(shù) 
ECHO ──────── 
ECHO (設(shè)定后要取消,單擊"確定"后按Ctrl+C鍵兩次) 
SET timed= 
SET /p timed=輸入: 
tsshutdn %timed% /delay:0 /powerdown >nul 
IF not errorlevel 1 GOTO ok 
ECHO %timed% 是無效的關(guān)機(jī)時間,請重新輸入 
ECHO. 
GOTO outtime 

:delAt 
cls 
echo. 
at /del /y 
echo 定時關(guān)機(jī)任務(wù)已取消,按任意鍵繼續(xù)... 
pause >nul 
GOTO start 

:view 
MODE con: COLS=85 LINES=18 
COLOR 70 
ECHO. 
at 
ECHO 按任意鍵繼續(xù)... 
PAUSE >nul 
GOTO start 

:restart 
shutdown -r -t 0 

:lock 
rundll32.exe user32.dll,LockWorkStation 
goto start 

:logoff 
logoff 

:end 
exit 