一、交互界面設(shè)計

沒啥說的，看看高手設(shè)計的菜單界面吧：

@echo off
cls
title 終極多功能修復(fù)
:menu
cls
color 0A
echo.
echo         ==============================
echo         請選擇要進行的操作，然后按回車
echo         ==============================
echo.
echo       1.網(wǎng)絡(luò)修復(fù)及上網(wǎng)相關(guān)設(shè)置,修復(fù)IE,自定義屏蔽網(wǎng)站
echo.
echo       2.病毒專殺工具，端口關(guān)閉工具,關(guān)閉自動播放
echo.
echo       3.清除所有多余的自啟動項目，修復(fù)系統(tǒng)錯誤
echo.
echo       4.清理系統(tǒng)垃圾,提高啟動速度
echo.
echo       Q.退出
echo.
echo.
:cho
set choice=
set /p choice=     請選擇:
IF NOT "%choice%"=="" SET choice=%choice:~0,1%
if /i "%choice%"=="1" goto ip
if /i "%choice%"=="2" goto setsave
if /i "%choice%"=="3" goto kaiji
if /i "%choice%"=="4" goto clean
if /i "%choice%"=="Q" goto endd
echo 選擇無效，請重新輸入
echo.
goto cho

只要學(xué)完本教程前面的章節(jié)，上面的程序應(yīng)該能看懂了。

二、if…else…條件語句

前面已經(jīng)談到，DOS條件語句主要有以下形式
IF [NOT] ERRORLEVEL number command
IF [NOT] string1==string2 command
IF [NOT] EXIST filename command
增強用法：IF [/I] string1 compare-op string2 command
增強用法中加上/I就不區(qū)分大小寫了!
增強用法中還有一些用來判斷數(shù)字的符號：

EQU - 等于
NEQ - 不等于
LSS - 小于
LEQ - 小于或等于
GTR - 大于
GEQ - 大于或等于

上面的command命令都可以用小括號來使用多條命令的組合，包括else子句，組合命令中可以嵌套使用條件或循環(huán)命令。

例如:

    IF EXIST filename (
        del filename
    ) ELSE (
        echo filename missing
    )

也可寫成：
if exist filename (del filename) else (echo filename missing)

但這種寫法不適合命令太多或嵌套命令的使用。

三、循環(huán)語句

1、指定次數(shù)循環(huán)

FOR /L %variable IN (start,step,end) DO command [command-parameters]

組合命令：
FOR /L %variable IN (start,step,end) DO (
Command1
Command2
……
)

2、對某集合執(zhí)行循環(huán)語句。

FOR %%variable IN (set) DO command [command-parameters]

  %%variable  指定一個單一字母可替換的參數(shù)。
  (set)      指定一個或一組文件?？梢允褂猛ㄅ浞?。
  command   對每個文件執(zhí)行的命令，可用小括號使用多條命令組合。

FOR /R [[drive:]path] %variable IN (set) DO command [command-parameters]

    檢查以 [drive:]path 為根的目錄樹，指向每個目錄中的
    FOR 語句。如果在 /R 后沒有指定目錄，則使用當前
目錄。如果集僅為一個單點(.)字符，則枚舉該目錄樹。

同前面一樣，command可以用括號來組合：
FOR /R [[drive:]path] %variable IN (set) DO (
Command1
Command2
……
commandn
)

3、條件循環(huán)

    上面的循環(huán)結(jié)構(gòu)是用for命令來實現(xiàn)的，for命令循環(huán)有一個缺點，就是整個循環(huán)被當作一條命令語句，涉及到變量延遲的問題。
    利用goto語句和條件判斷，dos可以實現(xiàn)條件循環(huán)，很簡單啦，看例子：

例：

@echo off
set var=0
rem ************循環(huán)開始了
:continue
set /a var+=1
echo 第%var%次循環(huán)
if %var% lss 100 goto continue
rem ************循環(huán)結(jié)束了
echo 循環(huán)執(zhí)行完畢
pause

例：

@echo off
set var=100
rem ************循環(huán)開始了
:continue
echo 第%var%次循環(huán)
set /a var-=1
if %var% gtr 0 goto continue
rem ************循環(huán)結(jié)束了
echo 循環(huán)執(zhí)行完畢
pause

四、子程序

在批處理程序中可以調(diào)用外部可運行程序，比如exe程序，也可調(diào)用其他批處理程序，這些也可以看作子程序，但是不夠方便，如果被調(diào)用的程序很多，就顯得不夠簡明了，很繁瑣。

在windowsXP中，批處理可以調(diào)用本程序中的一個程序段，相當于子程序，這些子程序一般放在主程序后面。

子程序調(diào)用格式：

CALL :label arguments

子程序語法：
:label
command1
command2
......
commandn
goto :eof

在子程序段中，參數(shù)%0指標簽:label

子過程一般放在最后，并且注意在主程序最后要加上exit或跳轉(zhuǎn)語句，避免錯誤的進入子過程。

子程序和主程序中的變量都是全局變量，其作用范圍都是整個批處理程序。

傳至子程序的參數(shù)在call語句中指定，在子程序中用%1、%2至%9的形式調(diào)用，而子程序返回主程序的數(shù)據(jù)只需在調(diào)用結(jié)束后直接引用就可以了，當然也可以指定返回變量，請看下面的例子。

子程序例1：

@echo off
call :sub return 你好
echo 子程序返回值：%return%
pause

:sub
set %1=%2
goto :eof

運行結(jié)果：你好

子程序例2：設(shè)計一個求多個整數(shù)相加的子程序

@echo off
set sum=0
call :sub sum 10 20 35
echo 數(shù)據(jù)求和結(jié)果：%sum%
pause

:sub
rem 參數(shù)1為返回變量名稱
set /a %1=%1+%2
shift /2
if not "%2"=="" goto sub
goto :eof

運行結(jié)果：65

在win98系統(tǒng)中，不支持上面這種標號調(diào)用，須將子程序單獨保存為一個批處理程序，然后調(diào)用。

五、用ftp命令實現(xiàn)自動下載

ftp是常用的下載工具，ftp界面中有40多個常用命令，自己學(xué)習(xí)了，不介紹了。這里介紹如何用dos命令行調(diào)用ftp命令，實現(xiàn)ftp自動登錄，并上傳下載，并自動退出ftp程序。

其實可以將ftp命令組合保存為一個文本文件，然后用以下命令調(diào)用即可。

ftp -n -s:[[drive:]path]filename

上面的filename為ftp命令文件，包括登錄IP地址，用戶名、密碼、操作命令等
例：

open 90.52.8.3 ＃打開ip
user iware ＃用戶為iware
password8848 ＃密碼
bin ＃二進制傳輸模式
prompt
cd tmp1 ＃切換至iware用戶下的tmp1目錄
pwd
lcd d:\download ＃本地目錄
mget * ＃下載tmp1目錄下的所有文件
bye ＃退出ftp

六、用7-ZIP實現(xiàn)命令行壓縮和解壓功能

語法格式：（詳細情況見7-zip幫助文件，看得頭暈可以跳過，用到再學(xué)）

7z <command> [<switch>...] <base_archive_name> [<arguments>...]

7z.exe的每個命令都有不同的參數(shù)<switch>,請看幫助文件
<base_archive_name>為壓縮包名稱
<arguments>為文件名稱，支持通配符或文件列表

其中，7z是至命令行壓縮解壓程序7z.exe，<command>是7z.exe包含的命令，列舉如下：

a： Adds files to archive. 添加至壓縮包
a命令可用參數(shù)：
-i (Include)
-m (Method)
-p (Set Password)
-r (Recurse)
-sfx (create SFX)
-si (use StdIn)
-so (use StdOut)
-ssw (Compress shared files)
-t (Type of archive)
-u (Update)
-v (Volumes)
-w (Working Dir)
-x (Exclude)

b： Benchmark

d： Deletes files from archive. 從壓縮包中刪除文件
d命令可用參數(shù)：
-i (Include)
-m (Method)
-p (Set Password)
-r (Recurse)
-u (Update)
-w (Working Dir)
-x (Exclude)

e： Extract解壓文件至當前目錄或指定目錄
e命令可用參數(shù)：
-ai (Include archives)
-an (Disable parsing of archive_name)
-ao (Overwrite mode)
-ax (Exclude archives)
-i (Include)
-o (Set Output Directory)
-p (Set Password)
-r (Recurse)
-so (use StdOut)
-x (Exclude)
-y (Assume Yes on all queries)

l： Lists contents of archive.
t： Test
u： Update

x： eXtract with full paths用文件的完整路徑解壓至當前目錄或指定目錄
x命令可用參數(shù)：
-ai (Include archives)
-an (Disable parsing of archive_name)
-ao (Overwrite mode)
-ax (Exclude archives)
-i (Include)
-o (Set Output Directory)
-p (Set Password)
-r (Recurse)
-so (use StdOut)
-x (Exclude)
-y (Assume Yes on all queries)

七、調(diào)用VBScript程序

使用 Windows 腳本宿主，可以在命令提示符下運行腳本。CScript.exe 提供了用于設(shè)置腳本屬性的命令行開關(guān)。

用法：CScript 腳本名稱 [腳本選項...] [腳本參數(shù)...]

選項：
//B 批模式：不顯示腳本錯誤及提示信息
//D 啟用 Active Debugging
//E:engine 使用執(zhí)行腳本的引擎
//H:CScript 將默認的腳本宿主改為 CScript.exe
//H:WScript 將默認的腳本宿主改為 WScript.exe （默認）
//I 交互模式（默認，與 //B 相對)
//Job:xxxx 執(zhí)行一個 WSF 工作
//Logo 顯示徽標（默認）
//Nologo 不顯示徽標：執(zhí)行時不顯示標志
//S 為該用戶保存當前命令行選項
//T:nn 超時設(shè)定秒：允許腳本運行的最長時間
//X 在調(diào)試器中執(zhí)行腳本
//U 用 Unicode 表示來自控制臺的重定向 I/O

“腳本名稱”是帶有擴展名和必需的路徑信息的腳本文件名稱，如d:\admin\vbscripts\chart.vbs。
“腳本選項和參數(shù)”將傳遞給腳本。腳本參數(shù)前面有一個斜杠 (/)。每個參數(shù)都是可選的；但不能在未指定腳本名稱的情況下指定腳本選項。如果未指定參數(shù)，則 CScript 將顯示 CScript 語法和有效的宿主參數(shù)。

八、將批處理轉(zhuǎn)化為可執(zhí)行文件：

由于批處理文件是一種文本文件，任何人都可以對其進行隨便編輯，不小心就會把里面的命令破壞掉，所以如果將其轉(zhuǎn)換成.com格式的可執(zhí)行文件，不僅執(zhí)行效率會大大提高，而且不會破壞原來的功能，更能將優(yōu)先級提到最高。Bat2Com就可以完成這個轉(zhuǎn)換工作。

小知識：在DOS環(huán)境下，可執(zhí)行文件的優(yōu)先級由高到低依次為.com>.exe>.bat>.cmd，即如果在同一目錄下存在文件名相 同的這四類文件，當只鍵入文件名時，DOS執(zhí)行的是name.com，如果需要執(zhí)行其他三個文件，則必須指定文件的全名，如name.bat。

這是一個只有5.43K大小的免費綠色工具，可以運行在純DOS或DOS窗口的命令行中，用法：Bat2Com FileName，這樣就會在同一目錄下生成一個名為FileNme.com的可執(zhí)行文件，執(zhí)行的效果和原來的.bat文件一樣。

九、時間延遲

什么是時間延遲？顧名思義，就是執(zhí)行一條命令后延遲一段時間再進行下一條命令。

延遲的應(yīng)用見下節(jié)：“模擬進度條”。

1、利用ping命令延時
例：

@echo off
echo 延時前：%time%
ping /n 3 127.0.0.1 >nul
echo 延時后：%time%
pause 

解說：用到了ping命令的“/n”參數(shù)，表示要發(fā)送多少次請求到指定的ip。本例中要發(fā)送3次請求到本機的ip（127.0.0.1）。127.0.0.1可簡寫為127.1。“>nul”就是屏蔽掉ping命令所顯示的內(nèi)容。

2、利用for命令延時
例：

@echo off
echo 延時前：%time%
for /l %%i in (1,1,5000) do echo %%i>nul
echo 延時后：%time%
pause

解說：原理很簡單，就是利用一個計次循環(huán)并屏蔽它所顯示的內(nèi)容來達到延時的目的。

3、利用vbs延遲函數(shù)，精確度毫秒，誤差1000毫秒內(nèi)

例：

@echo off
echo %time%
call :delay 5000
echo %time%
pause
exit

:delay
echo WScript.Sleep %1>delay.vbs
CScript //B delay.vbs
del delay.vbs
goto :eof

運行顯示：
10:44:06.45
10:44:11.95
請按任意鍵繼續(xù). . .

上面的運行結(jié)果顯示實際延時了5500毫秒，多出來的500毫秒時建立和刪除臨時文件所耗費的時間。誤差在一秒之內(nèi)。

4、僅用批處理命令實現(xiàn)任意時間延遲，精確度10毫秒，誤差50毫秒內(nèi)

僅用批處理命令就可以實現(xiàn)延遲操作。

例：

@echo off
set /p delay=請輸入需延遲的毫秒數(shù)：
set TotalTime=0
set NowTime=%time%
::讀取起始時間，時間格式為：13:01:05.95
echo 程序開始時間：%NowTime%
:delay_continue
set /a minute1=1%NowTime:~3,2%-100
::讀取起始時間的分鐘數(shù)
set /a second1=1%NowTime:~-5,2%%NowTime:~-2%0-100000
::將起始時間的秒數(shù)轉(zhuǎn)為毫秒
set NowTime=%time%
set /a minute2=1%NowTime:~3,2%-100
:: 讀取現(xiàn)在時間的分鐘數(shù)
set /a second2=1%NowTime:~-5,2%%NowTime:~-2%0-100000
::將現(xiàn)在時間的秒數(shù)轉(zhuǎn)為毫秒
set /a TotalTime+=(%minute2%-%minute1%+60)%%60*60000+%second2%-%second1%
if %TotalTime% lss %delay% goto delay_continue
echo 程序結(jié)束時間：%time%
echo 設(shè)定延遲時間：%delay%毫秒
echo 實際延遲時間：%TotalTime%毫秒
pause

運行顯示：

請輸入需延遲的毫秒數(shù)：6000
程序開始時間：15:32:16.37
程序結(jié)束時間：15:32:22.37
設(shè)定延遲時間：6000毫秒
實際延遲時間：6000毫秒
請按任意鍵繼續(xù). . .

實現(xiàn)原理：首先設(shè)定要延遲的毫秒數(shù)，然后用循環(huán)累加時間，直到累加時間大于等于延遲時間。

誤差：windows系統(tǒng)時間只能精確到10毫秒，所以理論上有可能存在10毫秒誤差。
經(jīng)測試，當延遲時間大于500毫秒時，上面的延遲程序一般不存在誤差。當延遲時間小于500毫秒時，可能有幾十毫秒誤差，為什么？因為延遲程序本身也是有運行時間的，同時系統(tǒng)時間只能精確到10毫秒。

為了方便引用，可將上面的例子改為子程序調(diào)用形式：

@echo off
echo 程序開始時間：%Time%
call :delay 10
echo 實際延遲時間：%totaltime%毫秒
echo 程序結(jié)束時間：%time%
pause
exit

::-----------以下為延時子程序--------------------
:delay
@echo off
if "%1"=="" goto :eof
set DelayTime=%1
set TotalTime=0
set NowTime=%time%
::讀取起始時間，時間格式為：13:01:05.95
:delay_continue
set /a minute1=1%NowTime:~3,2%-100
set /a second1=1%NowTime:~-5,2%%NowTime:~-2%0-100000
set NowTime=%time%
set /a minute2=1%NowTime:~3,2%-100
set /a second2=1%NowTime:~-5,2%%NowTime:~-2%0-100000
set /a TotalTime+=(%minute2%-%minute1%+60)%%60*60000+%second2%-%second1%
if %TotalTime% lss %DelayTime% goto delay_continue
goto :eof

十、模擬進度條

下面給出一個模擬進度條的程序。如果將它運用在你自己的程序中，可以使你的程序更漂亮。

@echo off
mode con cols=113 lines=15 &color 9f
cls
echo.
echo 程序正在初始化. . . 
echo.
echo ┌──────────────────────────────────────┐
set/p= ■<nul
for /L %%i in (1 1 38) do set /p a=■<nul&ping /n 1 127.0.0.1>nul
echo  100%%
echo └──────────────────────────────────────┘
pause

解說：“set /p a=■<nul”的意思是：只顯示提示信息“■”且不換行，也不需手工輸入任何信息，這樣可以使每個“■”在同一行逐個輸出?！皃ing /n 0 127.1>nul”是輸出每個“■”的時間間隔，即每隔多少時間輸出一個“■”。

十一、特殊字符的輸入及應(yīng)用

開始 -> 運行 -> 輸入cmd -> edit -> ctrl+p（意思是允許輸入特殊字符）-> 按ctrl+a將會顯示笑臉圖案。

（如果要繼續(xù)輸入特殊字符請再次按ctrl+p，然后ctrl+某個字母）

以上是特殊字符的輸入方法，選自[英雄]教程，很管用的。也就是用編輯程序edit輸入特殊字符，然后保存為一文本文件，再在windows下打開此文件，復(fù)制其中的特殊符號即可。

一些簡單的特殊符號可以在dos命令窗口直接輸入，并用重定向保存為文本文件。
例：

C:>ECHO ^G>temp.txt
“^G”是用Ctrl＋G或Alt＋007輸入，輸入多個^G可以產(chǎn)生多聲鳴響。

特殊字符的應(yīng)用也很有意思，這里僅舉一例：退格鍵

退格鍵表示刪除左邊的字符，此鍵不能在文檔中正常輸入，但可以通過edit編輯程序錄入并復(fù)制出來。即“”。

利用退格鍵，可以設(shè)計閃爍文字效果

例：文字閃爍

@echo off
:start
set/p=床前明月光<nul
::顯示文字，光標停于行尾
ping -n 0 127.0.0.1>nul
::設(shè)置延遲時間
set /p a=<nul
:: 輸出一些退格符將光標置于該行的最左端（退格符的數(shù)量可以自己調(diào)整）。
set /p a=                <nul
::輸出空格將之前輸出的文字覆蓋掉。
set /p a=<nul
::再次輸出退格符將光標置于該行的最左端，這里的退格符數(shù)量一定不能比前面的空格數(shù)少。
::否則光標不能退到最左端。
goto start

例：輸出唐詩一首，每行閃動多次

set str=床前明月光 疑是地上霜 舉頭望明月 低頭思故鄉(xiāng)

::定義字符串str
for %%i in (%str%) do (
 rem 由于str中含有空格，則以空格為分隔符將str中的每一個部分依次賦給變量%%i。
    set char=%%i
    echo.
    echo.
    for /l %%j in (0,1,5) do (
        set/p=!char:~%%j,1!<nul
 rem 依次取出變量char中的每一個字符，并顯示。
        ping -n 0 127.0.0.1>nul
 rem 設(shè)置輸出每個字符的時間延遲。
    )
 call :hero %%i
)
pause>nul
exit

:hero
for /l %%k in (1,1,10) do (
 ping /n 0 127.0.0.1>nul
 set /p a=<nul
 set /p a=                <nul
 set /p a=<nul
 ping /n 0 127.0.0.1>nul
 set /p a=%1<nul
)
::文字閃動
goto :eof

十二、隨機數(shù)（%random%）的應(yīng)用技巧

%RANDOM% 系統(tǒng)變量 返回 0 到 32767 之間的任意十進制數(shù)字。由 Cmd.exe 生成。

2的15次方等于32768，上面的0～32767實際就是15位二進制數(shù)的范圍。

那么，如何獲取100以內(nèi)的隨機數(shù)呢？很簡單，將%RANDOM%按100進行求余運算即可，見例子。

例：生成5個100以內(nèi)的隨機數(shù)

@echo off
setlocal enabledelayedexpansion
for /L %%i in (1 1 5) do (
  set /a randomNum=!random!%%100
  echo 隨機數(shù)：!randomNum!
)
pause

運行結(jié)果：（每次運行不一樣）
隨機數(shù)：91
隨機數(shù)：67
隨機數(shù)：58
隨機數(shù)：26
隨機數(shù)：20
請按任意鍵繼續(xù). . .

求余數(shù)運算set /a randomNum=!random!%%100中的100可以是1～32768之間的任意整數(shù)。

總結(jié)：利用系統(tǒng)變量%random%，求余數(shù)運算%%，字符串處理等，可以實現(xiàn)很多隨機處理。

思考題目：生成給定位數(shù)的隨機密碼

解答思路：將26個英文字母或10數(shù)字以及其它特殊字符組成一個字符串，隨機抽取其中的若干字符。

參考答案1：（簡單）

@echo off
call :randomPassword 5 pass1 pass2
echo %pass1% %pass2% 
pause
exit

:randomPassword
::---------生成隨機密碼
::---------%1為密碼長度，%2及以后為返回變量名稱
::---------for命令最多只能區(qū)分31個字段
@echo off
set password_len=%1
if not defined password_len goto :eof
if %password_len% lss 1 goto :eof
set wordset=a b c d e f g h i j k l m n o p q r s t u v w x y z
set return=
set num=0
:randomPassword1
set /a num+=1
set /a numof=%random%%%26+1
for /f "tokens=%numof% delims= " %%i in ("%wordset%") do set return=%return%%%i
if %num% lss %password_len% goto randomPassword1
if not "%2"=="" set %2=%return%
shift /2
if not "%2"=="" goto randomPassword
goto :eof

參考答案2：（最優(yōu)

@echo off
call :randomPassword 6 pass1 pass2 pass3
echo %pass1% %pass2% %pass3%
pause
exit

:randomPassword
::---------生成隨機密碼
::---------%1為密碼長度，%2及以后為返回變量名稱
::---------goto循環(huán)、變量嵌套、命令嵌套
@echo off
if "%1"=="" goto :eof
if %1 lss 1 goto :eof
set password_len=%1
set return=
set wordset=abcdefghijklmnopqrstuvwxyz023456789_
::---------------------------循環(huán)
:randomPassword1
set /a numof=%random%%%36
call set return=%return%%%wordset:~%numof%,1%%
set /a password_len-=1
if %password_len% gtr 0 goto randomPassword1
::---------------------------循環(huán)
if not "%2"=="" set %2=%return%
shift /2
if not "%2"=="" goto randomPassword
goto :eof

說明：本例涉及到變量嵌套和命令嵌套的應(yīng)用，見后。

十三、變量嵌套 與 命令嵌套

和其它編程語言相比，dos功能顯得相對簡單，要實現(xiàn)比較復(fù)雜的功能，需要充分運用各種技巧，變量嵌套與命令嵌套就是此類技巧之一。

先復(fù)習(xí)一下前面的“字符串截取”的關(guān)鍵內(nèi)容：

**********************************************
截取功能統(tǒng)一語法格式為：%a:~[m[,n]]%
**********************************************

方括號表示可選，%為變量標識符，a為變量名，不可少，冒號用于分隔變量名和說明部分，符號～可以簡單理解為“偏移”即可，m為偏移量（缺省為0），n為截取長度（缺省為全部）。

百分號如果需要當成單一字符，必須寫成%%

以上是dos變量處理的通用格式，如果其中的m、n為變量，那么這種情況就是變量嵌套了。

比如設(shè)變量word為“abcdefghij”，變量num為“123456789”
%word:~4,1%為e，其中4可以從變量num中取值，即%num:~3,1%，寫成組合形式如下：
%word:~%num:~3,1%,1% 經(jīng)測試這種寫法不能正確執(zhí)行，寫成%word:~(%num:~3,1%),1%同樣不行，那么，怎么實現(xiàn)這種變量嵌套呢？這就必須結(jié)合命令嵌套。

什么是命令嵌套呢？簡單的說，首先用一條dos命令生成一個字符串，而這個字符串是另一條dos命令，用call語句調(diào)用字符串將其執(zhí)行，從而得到最終結(jié)果。

例：用call語句實現(xiàn)命令嵌套

@echo off
set str1=aaa echo ok bbb
echo 初始字符串：%str1%
echo 生成命令字符串如下：
echo %str1:~4,7%
echo 運行命令字符串生成最終結(jié)果為：
call %str1:~4,7%
pause

運行顯示：
初始字符串：aaa echo ok bbb
生成命令字符串如下：
echo ok
運行命令字符串生成最終結(jié)果為：
ok
請按任意鍵繼續(xù). . .