sqlserver 通用存儲(chǔ)過(guò)程分頁(yè)代碼(附使用ROW_NUMBER()和不使用ROW_NUMBER()兩種情況性能分析)

更新時(shí)間：2010年05月23日 02:10:52 作者：

通用存儲(chǔ)過(guò)程分頁(yè)(使用ROW_NUMBER()和不使用ROW_NUMBER()兩種情況)性能分析

表結(jié)構(gòu)：

 
CREATE TABLE [dbo].[Xtest]( 
[ID] [bigint] IDENTITY(1,1) NOT NULL, 
[XName] [nvarchar](50) NULL, 
[XDemo] [nvarchar](500) NULL, 
CONSTRAINT [PK_xtest] PRIMARY KEY CLUSTERED 
( 
[ID] ASC 
)WITH (PAD_INDEX = OFF, STATISTICS_NORECOMPUTE = OFF, IGNORE_DUP_KEY = OFF, ALLOW_ROW_LOCKS = ON, ALLOW_PAGE_LOCKS = ON) ON [PRIMARY] 
) ON [PRIMARY] 

插入50萬(wàn)條數(shù)據(jù)：

復(fù)制代碼代碼如下:

 
declare @i int 
set @i=1 
while(@i<500001) 
begin 
insert into dbo.Xtest(XName,XDemo) values(CAST(@i as varchar)+'name'+CAST(@i as varchar),'這是第'+CAST(@i as varchar)+'的內(nèi)容') 
set @i=@i+1 
end 

另外對(duì)XName建立索引。
存儲(chǔ)過(guò)程如下：

復(fù)制代碼代碼如下:

 
-- ============================================= 
-- Author: <jiangrod> 
-- Create date: <2010-03-03> 
-- Description: <SQL2000通用分頁(yè)存儲(chǔ)過(guò)程>調(diào)用方法: sp_Pager2000 'xtest','*','ID','ORDER BY ID ASC','xname like ''%222name%''',3,20,0,0 
-- ============================================= 
ALTER PROCEDURE [dbo].[sp_Pager2000] 
@tblName varchar(255), -- 表名如：'xtest' 
@strGetFields varchar(1000) = '*', -- 需要返回的列如：'xname,xdemo' 
@pkName nvarchar(50)='ID', -- 主鍵名 
@strOrder varchar(255)='', -- 排序的字段名如：'order by id desc' 
@strWhere varchar(1500) = '', -- 查詢條件(注意:不要加where)如:'xname like ''%222name%''' 
@pageIndex int = 1, -- 頁(yè)碼如：2 
@pageSize int = 20, -- 每頁(yè)記錄數(shù)如：20 
@recordCount int=0 out, -- 記錄總數(shù) 
@doCount bit=0 -- 非0則統(tǒng)計(jì),為0則不統(tǒng)計(jì)(統(tǒng)計(jì)會(huì)影響效率) 
AS 
Declare @sql nvarchar(4000) 
Declare @sqltemp nvarchar(1000) 
set @sql=' From '+@tblName 
if(@strWhere!='') set @sql=@sql+' Where '+@strWhere 
declare @strCount nvarchar(1000) 
--總記錄條數(shù) 
if(@doCount!=0) 
begin 
if(@strWhere !='') 
begin 
set @strCount='set @num=(select count(1) from '+ @tblName + ' where '+@strWhere+' )' 
end 
else 
begin 
set @strCount='set @num=(select count(1) from '+ @tblName + ' )' 
end 
EXECUTE sp_executesql @strCount ,N'@num INT output',@RecordCount output 
end 
if @strWhere !='' 
begin 
set @strWhere=' where '+@strWhere 
end 
if (@PageIndex>1) 
begin 
set @sqltemp=@PKName+' not in (Select Top '+cast((@PageSize*(@PageIndex-1)) as nvarchar)+' '+@PKName+' '+@sql 
if(@strOrder!='')set @sqltemp=@sqltemp+' '+@strOrder 
set @sqltemp=@sqltemp+')' 
set @sql='Select Top '+cast(@PageSize as nvarchar)+' '+@strGetFields+' '+@sql 
if(@strWhere!='')set @sql=@sql+' And '+@sqltemp 
else set @sql=@sql+' Where '+@sqltemp 
end 
else 
begin 
set @sql='Select Top '+cast(@PageSize as nvarchar)+' '+@strGetFields+' '+@sql 
end 
if(@strOrder!='') set @sql=@sql+' '+@strOrder 
exec(@sql) 

-- ============================================= 
-- Author: <jiangrod> 
-- Create date: <2010-03-03> 
-- Description: <SQL2005及后續(xù)版本通用分頁(yè)存儲(chǔ)過(guò)程>調(diào)用方法: sp_Pager2005 'xtest','*','ORDER BY ID ASC','xname like ''%222name%''',2,20,0,0 
-- ============================================= 
ALTER PROCEDURE [dbo].[sp_Pager2005] 
@tblName varchar(255), -- 表名如：'xtest' 
@strGetFields varchar(1000) = '*', -- 需要返回的列如：'xname,xdemo' 
@strOrder varchar(255)='', -- 排序的字段名如：'order by id desc' 
@strWhere varchar(1500) = '', -- 查詢條件(注意:不要加where)如:'xname like ''%222name%''' 
@pageIndex int = 1, -- 頁(yè)碼如：2 
@pageSize int = 20, -- 每頁(yè)記錄數(shù)如：20 
@recordCount int output, -- 記錄總數(shù) 
@doCount bit=0 -- 非0則統(tǒng)計(jì),為0則不統(tǒng)計(jì)(統(tǒng)計(jì)會(huì)影響效率) 
AS 
declare @strSQL varchar(5000) 
declare @strCount nvarchar(1000) 
--總記錄條數(shù) 
if(@doCount!=0) 
begin 
if(@strWhere !='') 
begin 
set @strCount='set @num=(select count(1) from '+ @tblName + ' where '+@strWhere+' )' 
end 
else 
begin 
set @strCount='set @num=(select count(1) from '+ @tblName + ' )' 
end 
EXECUTE sp_executesql @strCount ,N'@num INT output',@RecordCount output 
end 
if @strWhere !='' 
begin 
set @strWhere=' where '+@strWhere 
end 
set @strSQL='SELECT * FROM (SELECT ROW_NUMBER() OVER ('+@strOrder+') AS ROWID,' 
set @strSQL=@strSQL+@strGetFields+' FROM ['+@tblName+'] '+@strWhere 
set @strSQL=@strSQL+') AS sp WHERE ROWID BETWEEN '+str((@PageIndex-1)*@PageSize+1) 
set @strSQL=@strSQL+' AND '+str(@PageIndex*@PageSize) 
exec (@strSQL) 

對(duì)上面兩個(gè)存儲(chǔ)過(guò)程進(jìn)行了測(cè)試,測(cè)試環(huán)境：酷睿2雙核2.20Gh,1G內(nèi)存,SQL SERVER2008
對(duì)50萬(wàn)條數(shù)據(jù)進(jìn)行了分頁(yè)查詢測(cè)試
查詢的條件是:xname like '%222name%'
"page1：2秒937毫秒":表示打開(kāi)第一頁(yè)使用的時(shí)間，其他依次類(lèi)推
不使用ROW_NUMBER()每頁(yè)都要統(tǒng)計(jì)：
page1：2秒937毫秒
page2：3秒140毫秒
page3：3秒453毫秒
page4：3秒609毫秒
page5：3秒843毫秒
page6：4秒156毫秒
不使用ROW_NUMBER()僅第一頁(yè)統(tǒng)計(jì)：
page1：2秒937毫秒
page2：0秒343毫秒
page3：0秒593毫秒
page4：0秒812毫秒
page5：1秒46毫秒
page6：1秒281毫秒
使用ROW_NUMBER()每頁(yè)都要統(tǒng)計(jì)：
page1：2秒937毫秒
page2：3秒31毫秒
page3：3秒156毫秒
page4：3秒296毫秒
page5：3秒421毫秒
page6：3秒515毫秒
使用ROW_NUMBER()僅第一頁(yè)統(tǒng)計(jì)：
page1：2秒937毫秒
page2：0秒218毫秒
page3：0秒359毫秒
page4：0秒468毫秒
page5：0秒578毫秒
page6：0秒687毫秒
結(jié)論：在存儲(chǔ)過(guò)程當(dāng)中如果每次都統(tǒng)計(jì)記錄總數(shù)將會(huì)嚴(yán)重影響效率，相同的查詢條件記錄總數(shù)必定是相同的，所以如果第一頁(yè)執(zhí)行之后把記錄總數(shù)保存起來(lái)，點(diǎn)擊其他頁(yè)次的時(shí)候命令存儲(chǔ)過(guò)
程不再統(tǒng)計(jì)記錄總數(shù)將會(huì)大大提高系統(tǒng)性能。通過(guò)測(cè)試結(jié)果看出每次都要統(tǒng)計(jì)總記錄數(shù)使用ROW_NUMBER()和不使用ROW_NUMBER()差別不是太大,如果僅第一次統(tǒng)計(jì)總記錄數(shù)使用ROW_NUMBER()將
會(huì)比不使用ROW_NUMBER()的效率提高很多。

您可能感興趣的文章: