先試試這個(gè):

procedure TForm1.Button1Click(Sender: TObject);
var
 i: Integer;
begin
 for i := 0 to 500000 do
 begin
  Canvas.TextOut(10, 10, IntToStr(i));
 end;
end;

上面程序運(yùn)行時(shí), 我們的窗體基本是 "死" 的, 可以在你在程序運(yùn)行期間拖動(dòng)窗體試試...

Delphi 為我們提供了一個(gè)簡(jiǎn)單的辦法(Application.ProcessMessages)來(lái)解決這個(gè)問(wèn)題:

procedure TForm1.Button1Click(Sender: TObject);
var
 i: Integer;
begin
 for i := 0 to 500000 do
 begin
  Canvas.TextOut(10, 10, IntToStr(i));
  Application.ProcessMessages;
 end;
end;

這個(gè) Application.ProcessMessages; 一般用在比較費(fèi)時(shí)的循環(huán)中, 它會(huì)檢查并先處理消息隊(duì)列中的其他消息.

但這算不上多線程, 譬如: 運(yùn)行中你拖動(dòng)窗體, 循環(huán)會(huì)暫停下來(lái)...

在使用多線程以前, 讓我們先簡(jiǎn)單修改一下程序:

function MyFun: Integer;
var
 i: Integer;
begin
 for i := 0 to 500000 do
 begin
  Form1.Canvas.Lock;
  Form1.Canvas.TextOut(10, 10, IntToStr(i));
  Form1.Canvas.Unlock;
 end;
 Result := 0;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
 MyFun;
end;

細(xì)數(shù)上面程序的變化:
1、首先這還不是多線程的, 也會(huì)讓窗體假 "死" 一會(huì);
2、把執(zhí)行代碼寫(xiě)在了一個(gè)函數(shù)里, 但這個(gè)函數(shù)不屬于 TForm1 的方法, 所以使用 Canvas 是必須冠以名稱(Form1);
3、既然是個(gè)函數(shù), (不管是否必要)都應(yīng)該有返回值;
4、使用了 500001 次 Lock 和 Unlock.

Canvas.Lock 好比在說(shuō): Canvas(繪圖表面)正忙著呢, 其他想用 Canvas 的等會(huì);
Canvas.Unlock : 用完了, 解鎖!

在 Canvas 中使用 Lock 和 Unlock 是個(gè)好習(xí)慣, 在不使用多線程的情況下這無(wú)所謂, 但保不準(zhǔn)哪天程序會(huì)擴(kuò)展為多線程的; 我們現(xiàn)在學(xué)習(xí)多線程, 當(dāng)然應(yīng)該用.

在 Delphi 中使用多線程有兩種方法: 調(diào)用 API、使用 TThread 類; 使用 API 的代碼更簡(jiǎn)單.

function MyFun(p: Pointer): Integer; stdcall;
var
 i: Integer;
begin
 for i := 0 to 500000 do
 begin
  Form1.Canvas.Lock;
  Form1.Canvas.TextOut(10, 10, IntToStr(i));
  Form1.Canvas.Unlock;
 end;
 Result := 0;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
 ID: THandle;
begin
 CreateThread(nil, 0, @MyFun, nil, 0, ID);
end;

代碼分析:
CreateThread 一個(gè)線程后, 算上原來(lái)的主線程, 這樣程序就有兩個(gè)線程、是標(biāo)準(zhǔn)的多線程了;
CreateThread 第三個(gè)參數(shù)是函數(shù)指針, 新線程建立后將立即執(zhí)行該函數(shù), 函數(shù)執(zhí)行完畢, 系統(tǒng)將銷毀此線程從而結(jié)束多線程的故事.

CreateThread 要使用的函數(shù)是系統(tǒng)級(jí)別的, 不能是某個(gè)類(譬如: TForm1)的方法, 并且有嚴(yán)格的格式(參數(shù)、返回值)要求, 不管你暫時(shí)是不是需要都必須按格式來(lái);
因?yàn)槭窍到y(tǒng)級(jí)調(diào)用, 還要綴上 stdcall, stdcall 是協(xié)調(diào)參數(shù)順序的, 雖然這里只有一個(gè)參數(shù)沒(méi)有順序可言, 但這是使用系統(tǒng)函數(shù)的慣例.

CreateThread 還需要一個(gè) var 參數(shù)來(lái)接受新建線程的 ID, 盡管暫時(shí)沒(méi)用, 但這也是格式; 其他參數(shù)以后再說(shuō)吧.

這樣一個(gè)最簡(jiǎn)單的多線程程序就出來(lái)了, 咱們?cè)儆?TThread 類實(shí)現(xiàn)一次

type
 TMyThread = class(TThread)
 protected
  procedure Execute; override;
 end;

procedure TMyThread.Execute;
var
 i: Integer;
begin
 FreeOnTerminate := True; {這可以讓線程執(zhí)行完畢后隨即釋放}
 for i := 0 to 500000 do
 begin
  Form1.Canvas.Lock;
  Form1.Canvas.TextOut(10, 10, IntToStr(i));
  Form1.Canvas.Unlock;
 end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
 TMyThread.Create(False);
end;

TThread 類有一個(gè)抽象方法(Execute), 因而是個(gè)抽象類, 抽象類只能繼承使用, 上面是繼承為 TMyThread.

繼承 TThread 主要就是實(shí)現(xiàn)抽象方法 Execute(把我們的代碼寫(xiě)在里面), 等我們的 TMyThread 實(shí)例化后, 首先就會(huì)執(zhí)行 Execute 方法中的代碼.

按常規(guī)我們一般這樣去實(shí)例化:

procedure TForm1.Button1Click(Sender: TObject);
var
 MyThread: TMyThread;
begin
 MyThread := TMyThread.Create(False);
end;

因?yàn)?MyThread 變量在這里毫無(wú)用處(并且編譯器還有提示), 所以不如直接寫(xiě)做 TMyThread.Create(False);

我們還可以輕松解決一個(gè)問(wèn)題, 如果: TMyThread.Create(True) ?
這樣線程建立后就不會(huì)立即調(diào)用 Execute, 可以在需要的時(shí)候再用 Resume 方法執(zhí)行線程, 譬如:

procedure TForm1.Button1Click(Sender: TObject);
var
 MyThread: TMyThread;
begin
 MyThread := TMyThread.Create(True);
 MyThread.Resume;
end;

//可簡(jiǎn)化為:
procedure TForm1.Button1Click(Sender: TObject);
begin
 with TMyThread.Create(True) do Resume;
end;

使用 TThread 類時(shí), Delphi 有提供的模板, 但用 IDE 寫(xiě)代碼很方便, 我重寫(xiě)一遍錄下來(lái)給大家看:



期間使用了 Ctrl+J、Shift+Ctrl+C、Ctrl+Alt+P 等快捷鍵.

重要的修正與補(bǔ)充:

在 TThread 類的例子中, 應(yīng)該有這句: FreeOnTerminate := True; (原來(lái)漏掉, 代碼中已加上; 但動(dòng)畫(huà)加不上了).

先說(shuō)它什么意思:
類 Create 了就要 Free;
但 TThread(的子類) 有特殊性, 很多時(shí)候我們不能確定新建的線程什么時(shí)候執(zhí)行完(也就是什么時(shí)候該釋放);
如果線程執(zhí)行完畢自己知道釋放就好了, 所以 TThread 給了一個(gè)布爾屬性 FreeOnTerminate, 如果為 True, 線程執(zhí)行完畢后就會(huì)自釋放.

我怎么會(huì)忽略了這么重要的問(wèn)題呢? 原因有二:
1、我一直在追求最精煉的代碼;
2、我手頭上不只一本書(shū)上介紹說(shuō): FreeOnTerminate 的默認(rèn)值是 True(錯(cuò)誤!), 經(jīng)落實(shí), 應(yīng)該是 False, 起碼在 Delphi 2007 和 2009 中是這樣; 或許以前的某個(gè)版本和現(xiàn)在不一樣.