asp+Access通用的自動(dòng)替換數(shù)據(jù)庫(kù)中的字符串

更新時(shí)間：2008年06月28日 01:14:08 作者：

幾年前寫的一個(gè)腳本，可以自動(dòng)進(jìn)行整庫(kù)的數(shù)據(jù)替換。

當(dāng)初只是為了玩玩寫的，沒(méi)想到寫了之后不斷有人詢問(wèn)，所以改寫了一下代碼，完善了一下，支持了正則替換，避開(kāi)了會(huì)導(dǎo)致出錯(cuò)的二進(jìn)制（ole對(duì)象），并且做了一個(gè)EXE的程序。感謝虛擬幫忙。
附asp代碼：

復(fù)制代碼代碼如下:

<%     
'####################################     
'批量替換數(shù)據(jù)庫(kù)內(nèi)容2008-3-17     
'替換是不可逆的，所以操作前做好能備份     
'####################################     
Dim Db,conn,Rs1,Rs2,Str1,Str2,I,Re     
str1="admi[0-z]" '要替換的字符串，支持正則     
str2="1234" '替換為的字符串     
Db="db.mdb" '數(shù)據(jù)庫(kù)地址     
'以下無(wú)需改動(dòng)     
'創(chuàng)建正則對(duì)象     
Set Re=new RegExp     
    Re.IgnoreCase =True    
    Re.Global=True    
Set Conn=Server.CreateObject("ADODB.Connection")     
    Conn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source="&server.mappath(Db)     
Set Rs1 = Conn.OpenSchema(20)     
    Do While Not Rs1.Eof     
        If UCase(Rs1("TABLE_TYPE"))="TABLE" Then '如果是用戶表,則進(jìn)行操作     
          Set Rs2=Server.Createobject("adodb.recordset")     
              Rs2.Open "select * from ["&Rs1("TABLE_NAME")"]",conn,1,3     
              Do While Not Rs2.Eof     
                For I=0 to Rs2.fields.count-1 '遍歷所有字段     
                    If Rs2(i).Properties("ISAUTOINCREMENT") = False And Rs2(i).Type<>128 And Rs2(i).Type<>204 And Rs2(i).Type<>205 Then '如果非自動(dòng)編號(hào)并且非ole對(duì)象     
                        Rs2(Rs2(i).name)=Myreplace(Rs2(i).value&"")     
                    End If    
                Next    
             Rs2.Movenext     
             Loop    
        Rs2.Close     
        Set Rs2=nothing     
        End If    
    Rs1.MoveNext     
    Loop    
Rs1.Close     
Set Rs1=Nothing    
Conn.close     
Set Conn=Nothing    
Set Re=Nothing    
Response.Write "替換完成"    

'自定義的替換函數(shù)     
Function myreplace(byval Tstr)     
If Tstr="" Or isnull(Tstr) Then      
 Exit Function    
Else    
    Re.Pattern=Str1     
    myReplace =Re.Replace(Tstr,Str2)     
End If    
End Function    
%> 