# Sets the minimum version of CMake required to build the native 
# library. You should either keep the default value or only pass a 
# value of 3.4.0 or lower. 
 
cmake_minimum_required(VERSION 3.4.1) 
 
##################################################################### 
 
# 這個是設(shè)置了編譯C的參數(shù)，這里使用C99并開啟三級優(yōu)化 
# 類似的設(shè)置還有CMAKE_CPP_FLAGS就是設(shè)置編譯C++的參數(shù) 
# 更多的參數(shù)就要根據(jù)需要看文檔了 
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -O3 -std=c99") 
 
##################################################################### 
 
# 這個函數(shù)是用來編譯庫的，主要是so文件和a文件。 
add_library( # 括號不在這一行語法錯誤 
  # 庫的名字自定義的 
  PNG    
 
  # static 就是a文件，shared 就是so文件  
  STATIC   
 
  # 這里提供的是預(yù)編譯好的文件，所以用這個imported， 
  # 否則需要提供需要編譯文件的列表 
  IMPORTED  
) 
 
# 設(shè)置編譯庫文件的屬性，有很多屬性設(shè)置，根據(jù)需要查看文檔 
set_target_properties( 
  # 設(shè)置哪個庫的編譯屬性 
  PNG         
 
  # 上面的PNG庫是預(yù)編譯的，這里的屬性表示文件所在的位置 
  PROPERTIES IMPORTED_LOCATION  
                 
  # 提供預(yù)編譯文件的位置。 
  # CMAKE_SOURCE_DIR 是內(nèi)置變量表示當(dāng)前CMakeLists.txt的位置。 
  # 這里需要提供絕對路徑所以需要這個變量， 
  # 下面會看到所有的設(shè)置都是相對于當(dāng)前文件的。但這個設(shè)置需要絕對路徑。 
  # ANDROID_ABI內(nèi)置變量，會根據(jù)當(dāng)前編譯的平臺分配一個文件夾名字， 
  # 比如armeabi-v7a， armeabi，x86等等 
  ${CMAKE_SOURCE_DIR}/PNG/Prebuilt/Android/${ANDROID_ABI}/libpng.a 
) 
 
##################################################################### 
 
# 表示編譯文件時候，頭文件的位置。路徑是相對于當(dāng)前文件的 
# 正確設(shè)置了這個路徑，在IDE中代碼頭文件也會正確索引。否則會無法定位頭文件。 
# 這里我們提供了代碼的文件的根目錄和PNG庫的頭文件目錄 
include_directories( 
  ../../../ 
  ../../External/PNG/Include/Android/ 
) 
 
# 另外一個用法。編譯so文件，自定義名字叫做NativeLib 
# 就像NDK Build的配置一樣，需要把源文件列表提供，不需要頭文件。 
# 這些源文件會編譯成一個NativeLib.so文件。 
# 值得一提的時候，在NDK Build中，我編譯一個沒有源文件的so文件， 
# 以后把其他的a文件整體連接進(jìn)來。這里不行，必須提供源文件至少一個。 
add_library( 
  NativeLib SHARED 
 
  ../../Toolkit/Toolkit.c 
  ../../Toolkit/Math/Math.c 
  ../../Toolkit/Math/Matrix.c 
  ../../Toolkit/Math/TweenEase.c 
  ../../Toolkit/Utils/Array.c 
  ../../Toolkit/Utils/ArrayList.c 
  ../../Toolkit/Utils/ArrayStrMap.c 
  ../../Toolkit/Utils/ArrayIntMap.c 
  ../../Toolkit/Utils/ArrayQueue.c 
  ../../Toolkit/Utils/BufferReader.c 
  ../../Toolkit/Utils/Json.c 
  ../../Toolkit/Utils/Tween.c 
  ../../Toolkit/Utils/TweenTool.c 
  ../../Toolkit/Platform/File.c 
) 
 
# 這是編譯一個a文件。可見此函數(shù)可以使用任意多個，編譯出多個庫文件。 
add_library( 
  EntryLink STATIC 
  ../../Application/EntryLink.c 
) 
 
# 這是連接一個庫文件。在庫文件使用了平臺，或是預(yù)編譯庫的接口文件，就需要在此連接。 
# 才能在運(yùn)行時正確調(diào)用到這些接口函數(shù)。 
target_link_libraries( 
  # 需要連接的庫名字，上面定義的任何一個庫都行。 
  NativeLib 
   
  # 這里奇怪的參數(shù)，是讓PNG這個庫直接拷貝到NativeLib里面。 
  # 因為并不打算把PNG這個庫單獨載入，平臺也不一定有這個庫， 
  # 于是就整體復(fù)制到NativeLib.so里面 
  "-Wl,--whole-archive"   
  PNG   
  "-Wl,--no-whole-archive"   
   
  # 這個庫存在的意義是 
  # 比如我在NativeLib用到了一些接口函數(shù)，希望留給另外一個庫使用。 
  # 連接的時候，不提供另外一個庫，或是那個庫還沒編譯。就會連接失敗找不到函數(shù)實現(xiàn)。 
  # 所以我們用這個庫實現(xiàn)空的函數(shù)，用作連接。 
  # 并不會放到NativeLib.so里。真正運(yùn)行的時候，有別的so庫文件提供。 
  EntryLink   
 
  # 以下就是Android平臺提供的庫直接寫名字就行了。官方文檔有說明哪些。 
  android        
  EGL   
  GLESv2   
  log   
  z 
) 

add_library(gmath STATIC src/gmath.c) 
set_target_properties(gmath 
           PROPERTIES 
           # 拷貝到下面的指定目錄，注意這個屬性名，這是拷貝a文件的。 
           ARCHIVE_OUTPUT_DIRECTORY  
           ${CMAKE_CURRENT_SOURCE_DIR}/lib/${ANDROID_ABI}) 
 
add_library(gperf SHARED src/gperf.c) 
set_target_properties(gperf 
           PROPERTIES 
           # 拷貝到下面的指定目錄，注意這個屬性名，這是拷貝so文件的。 
           LIBRARY_OUTPUT_DIRECTORY  
           ${CMAKE_CURRENT_SOURCE_DIR}/lib/${ANDROID_ABI}) 

# Sets the minimum version of CMake required to build the native 
# library. You should either keep the default value or only pass a 
# value of 3.4.0 or lower. 
 
cmake_minimum_required(VERSION 3.4.1) 
 
set(CMAKE_VERBOSE_MAKEFILE ON) 
 
##################################################################### 
 
# 第一個參數(shù)表示需要加載的子目錄CMakeLists.txt文件目錄 
# 第二個參數(shù)表示編譯這個文件內(nèi)容的中間文件目錄 
# 都是絕對路徑，所以我們使用了內(nèi)置變量，來跨平臺 
add_subdirectory( 
  ${CMAKE_SOURCE_DIR}/../../../NativeLib/Build/Android/ 
  ${CMAKE_SOURCE_DIR}/../../../NativeLib/Build/Android/Bin/ 
) 
 
##################################################################### 
 
include_directories( 
  ../../../ 
) 
 
add_library( 
  Development SHARED 
 
  ../AppInit.c 
  ../Tool.c 
  ../GameMap.c 
  ../Hero.c 
  ../Enemy.c 
  ../EnemyAI.c 
  ../GameActor.c 
) 
 
##################################################################### 
 
target_link_libraries( 
  Development 
  NativeLib 
) 

apply plugin: 'com.android.application' 
 
android { 
  compileSdkVersion 23 
  buildToolsVersion '25.0.0' 
  defaultConfig { 
    applicationId 'com.test.development' 
    minSdkVersion 19 
    targetSdkVersion 23 
    versionCode 1 
    versionName '1.0' 
    ndk { 
      // 這里控制NDK編譯哪些類型的ABI so文件，用來適配不同平臺 
      abiFilters 'armeabi-v7a' 
    } 
    externalNativeBuild { 
      // 使用cmake，還可以使用ndk 
      cmake { 
        arguments '-DANDROID_TOOLCHAIN=clang',  
             '-DANDROID_STL=system' 
        cFlags  '-std=c99' 
      } 
    } 
  } 
  buildTypes { 
    release { 
      minifyEnabled false 
      proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro' 
    } 
  } 
  externalNativeBuild { 
    cmake { 
      // 定位文件，link的時候自動生成 
      path '../../Build/Android/CMakeLists.txt' 
    } 
  } 
} 
 
dependencies { 
  compile fileTree(include: ['*.jar'], dir: 'libs') 
}